# List all required files here (cmake best practice to NOT automate this step!)
add_library(pls STATIC
            src/pls.cpp include/pls/pls.h
            src/internal/base/spin_lock.cpp include/pls/internal/base/spin_lock.h
            src/internal/base/thread.cpp include/pls/internal/base/thread.h
            include/pls/internal/helpers/prohibit_new.h
            src/internal/scheduling/abstract_task.cpp include/pls/internal/scheduling/abstract_task.h
            src/internal/scheduling/scheduler.cpp include/pls/internal/scheduling/scheduler.h
            src/internal/scheduling/thread_state.cpp  include/pls/internal/scheduling/thread_state.h
            src/internal/base/barrier.cpp include/pls/internal/base/barrier.h
            src/internal/scheduling/root_task.cpp include/pls/internal/scheduling/root_task.h
            src/internal/base/aligned_stack.cpp include/pls/internal/base/aligned_stack.h
            include/pls/internal/base/system_details.h
            src/internal/scheduling/run_on_n_threads_task.cpp include/pls/internal/scheduling/run_on_n_threads_task.h
            src/internal/scheduling/fork_join_task.cpp include/pls/internal/scheduling/fork_join_task.h
            src/internal/base/deque.cpp include/pls/internal/base/deque.h
            src/algorithms/invoke_parallel.cpp include/pls/algorithms/invoke_parallel.h
            include/pls/internal/base/error_handling.h
            include/pls/internal/scheduling/scheduler_memory.h src/internal/scheduling/scheduler_memory.cpp
            include/pls/internal/helpers/profiler.h
            include/pls/internal/helpers/mini_benchmark.h)

# Add everything in `./include` to be in the include path of this project
target_include_directories(pls
        PUBLIC
            $<INSTALL_INTERFACE:include>
            $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
        PRIVATE
            ${CMAKE_CURRENT_SOURCE_DIR}/src # TODO: Set this up when we require private headers
)

# Add cmake dependencies here if needed
target_link_libraries(pls
        Threads::Threads # pthread support
)
if(EASY_PROFILER)
    target_link_libraries(pls easy_profiler)
endif()

# Rules for istalling the library on a system
# ...binaries
INSTALL(TARGETS pls
        EXPORT pls-targets
        LIBRARY
            DESTINATION lib/pls
        ARCHIVE
            DESTINATION lib/pls
)
# ...all headers in `include`
INSTALL(
        DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/include/pls
        DESTINATION include
        FILES_MATCHING PATTERN "*.h*"
)
# ...allow our project to be a cmake dependency
install(
        EXPORT pls-targets
        FILE plsTargets.cmake
        NAMESPACE pls::
        DESTINATION lib/pls
)
INSTALl(
        FILES pls-config.cmake
        DESTINATION lib/pls
)

# Enable warnings/tidy code checking from our compiler
target_compile_options(pls PRIVATE
        $<$<OR:$<CXX_COMPILER_ID:Clang>,$<CXX_COMPILER_ID:AppleClang>,$<CXX_COMPILER_ID:GNU>>:
        -Wall>
        $<$<CXX_COMPILER_ID:MSVC>:
        -W4>)