CMakeLists.txt

# List all required files here (cmake best practice to NOT automate this step!)
add_library(pls STATIC
            src/library.cpp include/pls/library.h
            src/internal/base/spin_lock.cpp include/pls/internal/base/spin_lock.h
            src/internal/base/thread.cpp include/pls/internal/base/thread.h
            include/pls/internal/base/prohibit_new.h
            src/internal/scheduling/abstract_task.cpp include/pls/internal/scheduling/abstract_task.h
            src/internal/scheduling/scheduler.cpp include/pls/internal/scheduling/scheduler.h
            src/internal/scheduling/thread_state.cpp  include/pls/internal/scheduling/thread_state.h
            src/internal/base/barrier.cpp include/pls/internal/base/barrier.h
            src/internal/scheduling/root_master_task.cpp include/pls/internal/scheduling/root_master_task.h
            src/internal/base/aligned_stack.cpp include/pls/internal/base/aligned_stack.h
            include/pls/internal/base/system_details.h
            src/internal/scheduling/run_on_n_threads_task.cpp include/pls/internal/scheduling/run_on_n_threads_task.h)

# Add everything in `./include` to be in the include path of this project
target_include_directories(pls
        PUBLIC
            $<INSTALL_INTERFACE:include>
            $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
        PRIVATE
            ${CMAKE_CURRENT_SOURCE_DIR}/src # TODO: Set this up when we require private headers
)

# Add cmake dependencies here if needed
target_link_libraries(pls
        Threads::Threads # pthread support
)

# Rules for istalling the library on a system
# ...binaries
install(TARGETS pls
        LIBRARY
            DESTINATION lib
        ARCHIVE
            DESTINATION lib
)
# ...all headers in `include`
INSTALL (
        DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/include/
        DESTINATION include
        FILES_MATCHING PATTERN "*.h*"
)

# Enable warnings/tidy code checking from our compiler
target_compile_options(pls PRIVATE
        $<$<OR:$<CXX_COMPILER_ID:Clang>,$<CXX_COMPILER_ID:AppleClang>,$<CXX_COMPILER_ID:GNU>>:
        -Wall>
        $<$<CXX_COMPILER_ID:MSVC>:
        -W4>)